extends Control
class_name GameGui

signal game_click
signal day_pass_pressed
signal day_pass_proceed
signal day_pass_finished
signal pause_asked

func _on_player_updated(player:Player):
	%EnergyCount.text = str(player.energy)
	%EnergyInfo.modulate = Color.WHITE if player.energy > 0 else Color.RED

	%AvailableActions/GetItem.visible = player.closest_interactable is ItemObject and player.inventory.get_item() == null
	%AvailableActions/SwapItem.visible = player.closest_interactable is ItemObject and player.inventory.get_item() != null
	%AvailableActions/DropItem.visible = player.inventory.get_item() != null
	%AvailableActions/UseItem.visible = player.inventory.get_item() and player.can_use_item and not player.inventory.get_item() is Seed
	%AvailableActions/Plant.visible = player.inventory.get_item() and player.can_use_item and player.inventory.get_item() is Seed
	

	%ItemInfo.visible = player.inventory.get_item() != null
	if player.inventory.get_item():
		var item : Item = player.inventory.get_item()
		%ItemIcon.texture = item.icon
		%ItemName.text = item.name
		%ItemDesc.text = item.description

func _on_day_pass_pressed():
	day_pass_pressed.emit()
	$AnimationPlayer.play("recharge_fade_in")
	await $AnimationPlayer.animation_finished
	day_pass_proceed.emit()
	$AnimationPlayer.play("recharge_fade_out")
	await $AnimationPlayer.animation_finished
	day_pass_finished.emit()

func _on_game_action_button_down():
	game_click.emit()

func _on_planet_updated(planet:Planet):
	%DayCount.text = "Day " + str(planet.day)
	%DecontaminationCoverage.text = str(roundi(planet.decontamination_coverage * 100)) + "%"


func _on_player_action_tried_without_energy():
	$AnimationPlayer.play("no_energy_left")


func _on_pause_pressed():
	pause_asked.emit()