extends Node

signal inspected_entity_changed(e : InspectableEntity)

const DEFAULT_ACTION_COLOR = Color.WHITE
const ENERGY_ACTION_COLOR = Color("ffff2b")

@export var default_cursor : Texture2D

var inspected_entity : InspectableEntity = null :
	set(e):
		inspected_entity = e
		inspected_entity_changed.emit(e)
var player : Player # renseigné par Player
var can_interact : bool = false
var current_selected_item : Item = null
var can_use_item : bool = false

func _ready():
	Input.set_custom_mouse_cursor(default_cursor)
	%InspectorText.visible = false
	%Action.visible =  false

func _input(_event):
	if player:
		if Input.is_action_just_pressed("move"):
			player.try_move(
				player.get_global_mouse_position()
			)
		if Input.is_action_just_pressed("drop"):
			player.drop_item()

		if Input.is_action_just_pressed("action"):
			if can_interact:
				var interactable = inspected_entity as Interactable
				player.try_interact(interactable)
			elif can_use_item:
				player.try_use_item(
					player.inventory.get_item(),
					player.get_global_mouse_position()
				)

func _process(_delta):
	%Inspector.position = get_viewport().get_mouse_position()

	if player:
		can_interact = (
			inspected_entity
			and inspected_entity is Interactable
			and player.can_interact(inspected_entity)
		)

		current_selected_item = player.inventory.get_item() 

		can_use_item = (
			current_selected_item
			and player.preview_can_use_item(current_selected_item)
		)

	if current_selected_item:
		%ActionZone.radius = current_selected_item.usage_zone_radius
		%ActionZone.active = can_use_item
	else:
		%ActionZone.radius = 0
	
	%ActionZone.queue_redraw()

	update_inspector()

func inspect_entity(entity : InspectableEntity):
	if inspected_entity and inspected_entity != entity:
		inspected_entity.inspected = false
	inspected_entity = entity
	inspected_entity.inspected = true
	update_inspector()

func update_inspector():
	%InspectorText.visible = inspected_entity != null
	if inspected_entity:
		%InspectorText.text = inspected_entity.pointer_text()
	
	if player:
		if can_interact and inspected_entity and inspected_entity is Interactable:
			%Action.visible = true
			%ActionText.text = inspected_entity.interact_text()
			%Action.modulate = DEFAULT_ACTION_COLOR if inspected_entity.interaction_cost(player) == 0 else ENERGY_ACTION_COLOR
			%ActionEnergyImage.visible = inspected_entity.interaction_cost(player) != 0
		elif can_use_item and current_selected_item:
			%Action.visible = true
			%ActionText.text = current_selected_item.use_text()
			%Action.modulate = DEFAULT_ACTION_COLOR if current_selected_item.energy_usage == 0 else ENERGY_ACTION_COLOR
			%ActionEnergyImage.visible = current_selected_item.energy_usage != 0
		else:
			%Action.visible = false
		
	else:
		%Action.visible = false

func stop_inspect_entity(entity : InspectableEntity):
	entity.inspected = false
	if inspected_entity == entity:
		inspected_entity = null
	update_inspector()