@tool
extends Resource
class_name RunPoint

const DANGER_ICON = preload("res://common/icons/skull.svg")
const TYPE_ICON = preload("res://common/icons/map-pin.svg")
const OBJECTIVE_ICON = preload("res://common/icons/growth.svg")
const CHARGE_ICON = preload("res://common/icons/bolt.svg")

@export var level : int = 0 # X pos along the planet, and difficulty
@export var region_parameter : RegionParameter = RegionParameter.new() :
    set(v):
        region_parameter = v
@export var position : float = 0

func _init(
    _level : int = 0,
    _region_parameter : RegionParameter = RegionParameter.new(),
    _position : float = randf_range(0.,1.),
):
    level = _level
    region_parameter = _region_parameter
    region_parameter.level = level
    position = _position

func card_info() -> CardInfo:
    var info = CardInfo.new(
        region_parameter.region_name,
        tr("REGION_TO_VISIT")
    )

    info.type_icon = TYPE_ICON

    info.stats.append_array([
        CardStatInfo.new(str(region_parameter.get_objective()), OBJECTIVE_ICON),
        CardStatInfo.new(str(region_parameter.get_charge()), CHARGE_ICON),
    ])

    for m in region_parameter.modifiers:
        
        info.sections.append(m.card_section())

    return info