extends Resource
class_name RunData

enum State {STARTED, IN_PROGRESS, FINISHED}

const RUN_POINTS_NEXT_NUMBER : int = 2
const RUN_POINT_MAX_LEVEL = 5 # TODO

signal current_run_point_changed(rp : RunPoint)
signal artefacts_changed(artefact : Array[Artefact])

var run_seed = randi()
@export var next_run_points : Array[RunPoint] = generate_next_run_points()
@export var current_run_point : RunPoint = null :
    set(v):
        current_run_point = v
        current_run_point_changed.emit(v)
@export var visited_run_points : Array[RunPoint] = []

@export var last_used_modifier_name = ""

@export var artefacts : Array[Artefact] = []

var plant_info = RunDataPlantInfo.new(self)

func get_state() -> State:
    if not current_run_point:
        return State.STARTED
    elif current_run_point.level == RUN_POINT_MAX_LEVEL:
        return State.FINISHED
    else :
        return State.IN_PROGRESS

#region ------------------ Run Points ------------------

func generate_next_run_points(level = 0) -> Array[RunPoint]:
    
    next_run_points = []

    if level == RUN_POINT_MAX_LEVEL and GameInfo.game_data.game_mode == GameData.GameMode.STORY:
        return [
            generate_borea_base_run_point()
        ]

    for i in range(RUN_POINTS_NEXT_NUMBER):
        next_run_points.append(
            generate_next_run_point(level)
        )
    
    return next_run_points

func generate_next_run_point(level = 0) -> RunPoint:
    var region_parameter = RegionParameter.new()
    region_parameter.level = level
    region_parameter.modifiers = get_bad_region_modifiers()
    region_parameter.modifiers.append_array(get_good_region_modifiers())

    return RunPoint.new(
        level,
        region_parameter
    )

func generate_borea_base_run_point() -> RunPoint:
    var region_parameter = RegionParameter.new()
    region_parameter.level = RUN_POINT_MAX_LEVEL
    region_parameter.region_name = tr("BOREA_BASE")

    return RunPoint.new(
        RUN_POINT_MAX_LEVEL,
        region_parameter
    )

func get_next_run_points() -> Array[RunPoint]:
    if current_run_point and current_run_point.level == RUN_POINT_MAX_LEVEL:
        return []
    return next_run_points

func choose_next_run_point(run_point : RunPoint) -> RunPoint:
    if current_run_point:
        visited_run_points.append(current_run_point)
    current_run_point = run_point
    GameInfo.game_data.start_region(run_point.region_parameter)
    next_run_points = generate_next_run_points(current_run_point.level + 1)
    if len(current_run_point.region_parameter.modifiers):
        last_used_modifier_name = current_run_point.region_parameter.modifiers[0].get_modifier_name()
    return current_run_point

func get_good_region_modifiers() -> Array[RegionModifier]:
    return [VendingMachineModifier.new(),VendingMachineModifier.new()]

func get_bad_region_modifiers() -> Array[RegionModifier]:
    var possible_modifiers : Array[RegionModifier] = [
        AridModifier.new(),
        HumidModifier.new(),
        PoorModifier.new(),
        HarshModifier.new()
    ]

    possible_modifiers = possible_modifiers.filter(
        func (m): return m.get_modifier_name() != last_used_modifier_name
    )

    var choosen_modifier : RegionModifier = possible_modifiers.pick_random()

    last_used_modifier_name = choosen_modifier.get_modifier_name()

    return [choosen_modifier]

#endregion

#region ------------------ Artefacts ------------------

func add_artefacts(a: Artefact):
    artefacts.append(a)
    artefacts_changed.emit(artefacts)

#endregion