extends Resource
class_name RunData

const RUN_POINTS_NEXT_NUMBER : int = 2
const RUN_POINT_MAX_LEVEL = 5 # TODO

signal current_run_point_changed(rp : RunPoint)

var run_seed = randi()

@export var level = 0
@export var story_step : StoryStep
@export var next_run_points : Array[RunPoint]
@export var current_run_point : RunPoint = null :
    set(v):
        current_run_point = v
        current_run_point_changed.emit(v)

@export var artefacts : Array[Artefact] = []

var plant_info = RunDataPlantInfo.new(self)

func is_finished() -> bool:
    return story_step.is_run_finished(level)

func get_progress() -> int:
    return story_step.get_run_progress(level)

#region ------------------ Run Points ------------------

func generate_next_run_points() -> Array[RunPoint]:
    next_run_points = []

    for i in range(story_step.get_run_point_number(level+1)):
        var last_modifiers : Array[String] = []
        if len(next_run_points):
            for m in next_run_points[0].region_parameter.modifiers:
                last_modifiers.append(m.modifier_name)
        next_run_points.append(
            generate_next_run_point(last_modifiers)
        )
    
    return next_run_points

func generate_next_run_point(last_modifiers : Array[String] = []) -> RunPoint:
    var region_parameter = RegionParameter.new()
    
    var next_level = level+1

    var challenge_modifiers = generate_challenge_modifiers().filter(
        func(m : RegionModifier): return not m.modifier_name in last_modifiers
    )
    var benefic_modifiers = generate_benefic_modifiers().filter(
        func(m : RegionModifier): return not m.modifier_name in last_modifiers
    )
    var normal_modifiers = generate_normal_modifiers().filter(
        func(m : RegionModifier): return not m.modifier_name in last_modifiers
    )

    if story_step.need_gameplay_modifier(next_level):
        var is_challenge = randf() < story_step.get_challenge_chance(next_level)
        if is_challenge:
            region_parameter.modifiers = [
                challenge_modifiers.pick_random(),
                benefic_modifiers.pick_random()
            ] as Array[RegionModifier]
        else:
            region_parameter.modifiers = [
                normal_modifiers.pick_random()
            ] as Array[RegionModifier]


        region_parameter.modifiers.append_array(
            story_step.get_gameplay_modifiers_for_region(next_level)
        )

    region_parameter.modifiers.append_array(
        story_step.get_story_modifiers_for_region(next_level)
    )
    
    region_parameter.objective = story_step.get_objective_for_region(next_level)
    region_parameter.charge = story_step.get_charge_number(next_level)


    return RunPoint.new(
        region_parameter
    )


func choose_next_run_point(run_point : RunPoint = null) -> RunPoint:
    if run_point == null:
        run_point = generate_next_run_point()
    level += 1
    current_run_point = run_point
    GameInfo.game_data.start_region(run_point.region_parameter)
    next_run_points = generate_next_run_points()
    return current_run_point

#endregion

#region ------------------ Modifiers ------------------

func generate_normal_modifiers() -> Array[RegionModifier]:
    return [
        AridModifier.new(),
        HumidModifier.new(),
        PoorModifier.new(),
        HarshModifier.new(),
        ToxicModifier.new(),
        SandyModifier.new(),
        MagneticModifier.new(),
    ]

func generate_benefic_modifiers() -> Array[RegionModifier]:
    return [
        VendingMachineModifier.new(),
        ResonnanceModifier.new(),
        InstableModifier.new(),
        CaveModifier.new(),
    ]


func generate_challenge_modifiers() -> Array[RegionModifier]:
    return [
        RockyModifier.new(),
        RadioactiveModifier.new(),
        ContaminatedModifier.new(),
        StormModifier.new(),
    ]

#endregion

#region ------------------ Artefacts ------------------

func add_artefacts(a: Artefact):
    artefacts.append(a)
    GameInfo.game_data.player_data.update_with_artefacts(artefacts)

#endregion